Leon Scroggins III | 3993b37 | 2018-07-16 10:43:45 -0400 | [diff] [blame] | 1 | ; |
| 2 | ; jidctint.asm - accurate integer IDCT (MMX) |
| 3 | ; |
| 4 | ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB |
| 5 | ; Copyright (C) 2016, D. R. Commander. |
| 6 | ; |
| 7 | ; Based on the x86 SIMD extension for IJG JPEG library |
| 8 | ; Copyright (C) 1999-2006, MIYASAKA Masaru. |
| 9 | ; For conditions of distribution and use, see copyright notice in jsimdext.inc |
| 10 | ; |
| 11 | ; This file should be assembled with NASM (Netwide Assembler), |
| 12 | ; can *not* be assembled with Microsoft's MASM or any compatible |
| 13 | ; assembler (including Borland's Turbo Assembler). |
| 14 | ; NASM is available from http://nasm.sourceforge.net/ or |
| 15 | ; http://sourceforge.net/project/showfiles.php?group_id=6208 |
| 16 | ; |
| 17 | ; This file contains a slow-but-accurate integer implementation of the |
| 18 | ; inverse DCT (Discrete Cosine Transform). The following code is based |
| 19 | ; directly on the IJG's original jidctint.c; see the jidctint.c for |
| 20 | ; more details. |
Leon Scroggins III | 3993b37 | 2018-07-16 10:43:45 -0400 | [diff] [blame] | 21 | |
| 22 | %include "jsimdext.inc" |
| 23 | %include "jdct.inc" |
| 24 | |
| 25 | ; -------------------------------------------------------------------------- |
| 26 | |
| 27 | %define CONST_BITS 13 |
| 28 | %define PASS1_BITS 2 |
| 29 | |
| 30 | %define DESCALE_P1 (CONST_BITS - PASS1_BITS) |
| 31 | %define DESCALE_P2 (CONST_BITS + PASS1_BITS + 3) |
| 32 | |
| 33 | %if CONST_BITS == 13 |
| 34 | F_0_298 equ 2446 ; FIX(0.298631336) |
| 35 | F_0_390 equ 3196 ; FIX(0.390180644) |
| 36 | F_0_541 equ 4433 ; FIX(0.541196100) |
| 37 | F_0_765 equ 6270 ; FIX(0.765366865) |
| 38 | F_0_899 equ 7373 ; FIX(0.899976223) |
| 39 | F_1_175 equ 9633 ; FIX(1.175875602) |
| 40 | F_1_501 equ 12299 ; FIX(1.501321110) |
| 41 | F_1_847 equ 15137 ; FIX(1.847759065) |
| 42 | F_1_961 equ 16069 ; FIX(1.961570560) |
| 43 | F_2_053 equ 16819 ; FIX(2.053119869) |
| 44 | F_2_562 equ 20995 ; FIX(2.562915447) |
| 45 | F_3_072 equ 25172 ; FIX(3.072711026) |
| 46 | %else |
| 47 | ; NASM cannot do compile-time arithmetic on floating-point constants. |
| 48 | %define DESCALE(x, n) (((x) + (1 << ((n) - 1))) >> (n)) |
| 49 | F_0_298 equ DESCALE( 320652955, 30 - CONST_BITS) ; FIX(0.298631336) |
| 50 | F_0_390 equ DESCALE( 418953276, 30 - CONST_BITS) ; FIX(0.390180644) |
| 51 | F_0_541 equ DESCALE( 581104887, 30 - CONST_BITS) ; FIX(0.541196100) |
| 52 | F_0_765 equ DESCALE( 821806413, 30 - CONST_BITS) ; FIX(0.765366865) |
| 53 | F_0_899 equ DESCALE( 966342111, 30 - CONST_BITS) ; FIX(0.899976223) |
| 54 | F_1_175 equ DESCALE(1262586813, 30 - CONST_BITS) ; FIX(1.175875602) |
| 55 | F_1_501 equ DESCALE(1612031267, 30 - CONST_BITS) ; FIX(1.501321110) |
| 56 | F_1_847 equ DESCALE(1984016188, 30 - CONST_BITS) ; FIX(1.847759065) |
| 57 | F_1_961 equ DESCALE(2106220350, 30 - CONST_BITS) ; FIX(1.961570560) |
| 58 | F_2_053 equ DESCALE(2204520673, 30 - CONST_BITS) ; FIX(2.053119869) |
| 59 | F_2_562 equ DESCALE(2751909506, 30 - CONST_BITS) ; FIX(2.562915447) |
| 60 | F_3_072 equ DESCALE(3299298341, 30 - CONST_BITS) ; FIX(3.072711026) |
| 61 | %endif |
| 62 | |
| 63 | ; -------------------------------------------------------------------------- |
| 64 | SECTION SEG_CONST |
| 65 | |
| 66 | alignz 32 |
| 67 | GLOBAL_DATA(jconst_idct_islow_mmx) |
| 68 | |
| 69 | EXTN(jconst_idct_islow_mmx): |
| 70 | |
| 71 | PW_F130_F054 times 2 dw (F_0_541 + F_0_765), F_0_541 |
| 72 | PW_F054_MF130 times 2 dw F_0_541, (F_0_541 - F_1_847) |
| 73 | PW_MF078_F117 times 2 dw (F_1_175 - F_1_961), F_1_175 |
| 74 | PW_F117_F078 times 2 dw F_1_175, (F_1_175 - F_0_390) |
| 75 | PW_MF060_MF089 times 2 dw (F_0_298 - F_0_899), -F_0_899 |
| 76 | PW_MF089_F060 times 2 dw -F_0_899, (F_1_501 - F_0_899) |
| 77 | PW_MF050_MF256 times 2 dw (F_2_053 - F_2_562), -F_2_562 |
| 78 | PW_MF256_F050 times 2 dw -F_2_562, (F_3_072 - F_2_562) |
| 79 | PD_DESCALE_P1 times 2 dd 1 << (DESCALE_P1 - 1) |
| 80 | PD_DESCALE_P2 times 2 dd 1 << (DESCALE_P2 - 1) |
| 81 | PB_CENTERJSAMP times 8 db CENTERJSAMPLE |
| 82 | |
| 83 | alignz 32 |
| 84 | |
| 85 | ; -------------------------------------------------------------------------- |
| 86 | SECTION SEG_TEXT |
| 87 | BITS 32 |
| 88 | ; |
| 89 | ; Perform dequantization and inverse DCT on one block of coefficients. |
| 90 | ; |
| 91 | ; GLOBAL(void) |
| 92 | ; jsimd_idct_islow_mmx(void *dct_table, JCOEFPTR coef_block, |
| 93 | ; JSAMPARRAY output_buf, JDIMENSION output_col) |
| 94 | ; |
| 95 | |
| 96 | %define dct_table(b) (b) + 8 ; jpeg_component_info *compptr |
| 97 | %define coef_block(b) (b) + 12 ; JCOEFPTR coef_block |
| 98 | %define output_buf(b) (b) + 16 ; JSAMPARRAY output_buf |
| 99 | %define output_col(b) (b) + 20 ; JDIMENSION output_col |
| 100 | |
| 101 | %define original_ebp ebp + 0 |
| 102 | %define wk(i) ebp - (WK_NUM - (i)) * SIZEOF_MMWORD |
| 103 | ; mmword wk[WK_NUM] |
| 104 | %define WK_NUM 12 |
| 105 | %define workspace wk(0) - DCTSIZE2 * SIZEOF_JCOEF |
| 106 | ; JCOEF workspace[DCTSIZE2] |
| 107 | |
| 108 | align 32 |
| 109 | GLOBAL_FUNCTION(jsimd_idct_islow_mmx) |
| 110 | |
| 111 | EXTN(jsimd_idct_islow_mmx): |
| 112 | push ebp |
| 113 | mov eax, esp ; eax = original ebp |
| 114 | sub esp, byte 4 |
| 115 | and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits |
| 116 | mov [esp], eax |
| 117 | mov ebp, esp ; ebp = aligned ebp |
| 118 | lea esp, [workspace] |
| 119 | push ebx |
| 120 | ; push ecx ; need not be preserved |
| 121 | ; push edx ; need not be preserved |
| 122 | push esi |
| 123 | push edi |
| 124 | |
| 125 | get_GOT ebx ; get GOT address |
| 126 | |
| 127 | ; ---- Pass 1: process columns from input, store into work array. |
| 128 | |
| 129 | ; mov eax, [original_ebp] |
| 130 | mov edx, POINTER [dct_table(eax)] ; quantptr |
| 131 | mov esi, JCOEFPTR [coef_block(eax)] ; inptr |
| 132 | lea edi, [workspace] ; JCOEF *wsptr |
| 133 | mov ecx, DCTSIZE/4 ; ctr |
| 134 | alignx 16, 7 |
| 135 | .columnloop: |
| 136 | %ifndef NO_ZERO_COLUMN_TEST_ISLOW_MMX |
Jake Weinstein | 8683f0e | 2020-08-21 18:48:40 +0200 | [diff] [blame^] | 137 | mov eax, dword [DWBLOCK(1,0,esi,SIZEOF_JCOEF)] |
| 138 | or eax, dword [DWBLOCK(2,0,esi,SIZEOF_JCOEF)] |
Leon Scroggins III | 3993b37 | 2018-07-16 10:43:45 -0400 | [diff] [blame] | 139 | jnz short .columnDCT |
| 140 | |
| 141 | movq mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)] |
| 142 | movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)] |
| 143 | por mm0, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)] |
| 144 | por mm1, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)] |
| 145 | por mm0, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)] |
| 146 | por mm1, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)] |
| 147 | por mm0, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)] |
| 148 | por mm1, mm0 |
| 149 | packsswb mm1, mm1 |
| 150 | movd eax, mm1 |
| 151 | test eax, eax |
| 152 | jnz short .columnDCT |
| 153 | |
| 154 | ; -- AC terms all zero |
| 155 | |
| 156 | movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)] |
| 157 | pmullw mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 158 | |
| 159 | psllw mm0, PASS1_BITS |
| 160 | |
| 161 | movq mm2, mm0 ; mm0=in0=(00 01 02 03) |
| 162 | punpcklwd mm0, mm0 ; mm0=(00 00 01 01) |
| 163 | punpckhwd mm2, mm2 ; mm2=(02 02 03 03) |
| 164 | |
| 165 | movq mm1, mm0 |
| 166 | punpckldq mm0, mm0 ; mm0=(00 00 00 00) |
| 167 | punpckhdq mm1, mm1 ; mm1=(01 01 01 01) |
| 168 | movq mm3, mm2 |
| 169 | punpckldq mm2, mm2 ; mm2=(02 02 02 02) |
| 170 | punpckhdq mm3, mm3 ; mm3=(03 03 03 03) |
| 171 | |
| 172 | movq MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0 |
| 173 | movq MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm0 |
| 174 | movq MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm1 |
| 175 | movq MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm1 |
| 176 | movq MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm2 |
| 177 | movq MMWORD [MMBLOCK(2,1,edi,SIZEOF_JCOEF)], mm2 |
| 178 | movq MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm3 |
| 179 | movq MMWORD [MMBLOCK(3,1,edi,SIZEOF_JCOEF)], mm3 |
| 180 | jmp near .nextcolumn |
| 181 | alignx 16, 7 |
| 182 | %endif |
| 183 | .columnDCT: |
| 184 | |
| 185 | ; -- Even part |
| 186 | |
| 187 | movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)] |
| 188 | movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)] |
| 189 | pmullw mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 190 | pmullw mm1, MMWORD [MMBLOCK(2,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 191 | movq mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)] |
| 192 | movq mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)] |
| 193 | pmullw mm2, MMWORD [MMBLOCK(4,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 194 | pmullw mm3, MMWORD [MMBLOCK(6,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 195 | |
| 196 | ; (Original) |
| 197 | ; z1 = (z2 + z3) * 0.541196100; |
| 198 | ; tmp2 = z1 + z3 * -1.847759065; |
| 199 | ; tmp3 = z1 + z2 * 0.765366865; |
| 200 | ; |
| 201 | ; (This implementation) |
| 202 | ; tmp2 = z2 * 0.541196100 + z3 * (0.541196100 - 1.847759065); |
| 203 | ; tmp3 = z2 * (0.541196100 + 0.765366865) + z3 * 0.541196100; |
| 204 | |
| 205 | movq mm4, mm1 ; mm1=in2=z2 |
| 206 | movq mm5, mm1 |
| 207 | punpcklwd mm4, mm3 ; mm3=in6=z3 |
| 208 | punpckhwd mm5, mm3 |
| 209 | movq mm1, mm4 |
| 210 | movq mm3, mm5 |
| 211 | pmaddwd mm4, [GOTOFF(ebx,PW_F130_F054)] ; mm4=tmp3L |
| 212 | pmaddwd mm5, [GOTOFF(ebx,PW_F130_F054)] ; mm5=tmp3H |
| 213 | pmaddwd mm1, [GOTOFF(ebx,PW_F054_MF130)] ; mm1=tmp2L |
| 214 | pmaddwd mm3, [GOTOFF(ebx,PW_F054_MF130)] ; mm3=tmp2H |
| 215 | |
| 216 | movq mm6, mm0 |
| 217 | paddw mm0, mm2 ; mm0=in0+in4 |
| 218 | psubw mm6, mm2 ; mm6=in0-in4 |
| 219 | |
| 220 | pxor mm7, mm7 |
| 221 | pxor mm2, mm2 |
| 222 | punpcklwd mm7, mm0 ; mm7=tmp0L |
| 223 | punpckhwd mm2, mm0 ; mm2=tmp0H |
| 224 | psrad mm7, (16-CONST_BITS) ; psrad mm7,16 & pslld mm7,CONST_BITS |
| 225 | psrad mm2, (16-CONST_BITS) ; psrad mm2,16 & pslld mm2,CONST_BITS |
| 226 | |
| 227 | movq mm0, mm7 |
| 228 | paddd mm7, mm4 ; mm7=tmp10L |
| 229 | psubd mm0, mm4 ; mm0=tmp13L |
| 230 | movq mm4, mm2 |
| 231 | paddd mm2, mm5 ; mm2=tmp10H |
| 232 | psubd mm4, mm5 ; mm4=tmp13H |
| 233 | |
| 234 | movq MMWORD [wk(0)], mm7 ; wk(0)=tmp10L |
| 235 | movq MMWORD [wk(1)], mm2 ; wk(1)=tmp10H |
| 236 | movq MMWORD [wk(2)], mm0 ; wk(2)=tmp13L |
| 237 | movq MMWORD [wk(3)], mm4 ; wk(3)=tmp13H |
| 238 | |
| 239 | pxor mm5, mm5 |
| 240 | pxor mm7, mm7 |
| 241 | punpcklwd mm5, mm6 ; mm5=tmp1L |
| 242 | punpckhwd mm7, mm6 ; mm7=tmp1H |
| 243 | psrad mm5, (16-CONST_BITS) ; psrad mm5,16 & pslld mm5,CONST_BITS |
| 244 | psrad mm7, (16-CONST_BITS) ; psrad mm7,16 & pslld mm7,CONST_BITS |
| 245 | |
| 246 | movq mm2, mm5 |
| 247 | paddd mm5, mm1 ; mm5=tmp11L |
| 248 | psubd mm2, mm1 ; mm2=tmp12L |
| 249 | movq mm0, mm7 |
| 250 | paddd mm7, mm3 ; mm7=tmp11H |
| 251 | psubd mm0, mm3 ; mm0=tmp12H |
| 252 | |
| 253 | movq MMWORD [wk(4)], mm5 ; wk(4)=tmp11L |
| 254 | movq MMWORD [wk(5)], mm7 ; wk(5)=tmp11H |
| 255 | movq MMWORD [wk(6)], mm2 ; wk(6)=tmp12L |
| 256 | movq MMWORD [wk(7)], mm0 ; wk(7)=tmp12H |
| 257 | |
| 258 | ; -- Odd part |
| 259 | |
| 260 | movq mm4, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)] |
| 261 | movq mm6, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)] |
| 262 | pmullw mm4, MMWORD [MMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 263 | pmullw mm6, MMWORD [MMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 264 | movq mm1, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)] |
| 265 | movq mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)] |
| 266 | pmullw mm1, MMWORD [MMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 267 | pmullw mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)] |
| 268 | |
| 269 | movq mm5, mm6 |
| 270 | movq mm7, mm4 |
| 271 | paddw mm5, mm3 ; mm5=z3 |
| 272 | paddw mm7, mm1 ; mm7=z4 |
| 273 | |
| 274 | ; (Original) |
| 275 | ; z5 = (z3 + z4) * 1.175875602; |
| 276 | ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644; |
| 277 | ; z3 += z5; z4 += z5; |
| 278 | ; |
| 279 | ; (This implementation) |
| 280 | ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602; |
| 281 | ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644); |
| 282 | |
| 283 | movq mm2, mm5 |
| 284 | movq mm0, mm5 |
| 285 | punpcklwd mm2, mm7 |
| 286 | punpckhwd mm0, mm7 |
| 287 | movq mm5, mm2 |
| 288 | movq mm7, mm0 |
| 289 | pmaddwd mm2, [GOTOFF(ebx,PW_MF078_F117)] ; mm2=z3L |
| 290 | pmaddwd mm0, [GOTOFF(ebx,PW_MF078_F117)] ; mm0=z3H |
| 291 | pmaddwd mm5, [GOTOFF(ebx,PW_F117_F078)] ; mm5=z4L |
| 292 | pmaddwd mm7, [GOTOFF(ebx,PW_F117_F078)] ; mm7=z4H |
| 293 | |
| 294 | movq MMWORD [wk(10)], mm2 ; wk(10)=z3L |
| 295 | movq MMWORD [wk(11)], mm0 ; wk(11)=z3H |
| 296 | |
| 297 | ; (Original) |
| 298 | ; z1 = tmp0 + tmp3; z2 = tmp1 + tmp2; |
| 299 | ; tmp0 = tmp0 * 0.298631336; tmp1 = tmp1 * 2.053119869; |
| 300 | ; tmp2 = tmp2 * 3.072711026; tmp3 = tmp3 * 1.501321110; |
| 301 | ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447; |
| 302 | ; tmp0 += z1 + z3; tmp1 += z2 + z4; |
| 303 | ; tmp2 += z2 + z3; tmp3 += z1 + z4; |
| 304 | ; |
| 305 | ; (This implementation) |
| 306 | ; tmp0 = tmp0 * (0.298631336 - 0.899976223) + tmp3 * -0.899976223; |
| 307 | ; tmp1 = tmp1 * (2.053119869 - 2.562915447) + tmp2 * -2.562915447; |
| 308 | ; tmp2 = tmp1 * -2.562915447 + tmp2 * (3.072711026 - 2.562915447); |
| 309 | ; tmp3 = tmp0 * -0.899976223 + tmp3 * (1.501321110 - 0.899976223); |
| 310 | ; tmp0 += z3; tmp1 += z4; |
| 311 | ; tmp2 += z3; tmp3 += z4; |
| 312 | |
| 313 | movq mm2, mm3 |
| 314 | movq mm0, mm3 |
| 315 | punpcklwd mm2, mm4 |
| 316 | punpckhwd mm0, mm4 |
| 317 | movq mm3, mm2 |
| 318 | movq mm4, mm0 |
| 319 | pmaddwd mm2, [GOTOFF(ebx,PW_MF060_MF089)] ; mm2=tmp0L |
| 320 | pmaddwd mm0, [GOTOFF(ebx,PW_MF060_MF089)] ; mm0=tmp0H |
| 321 | pmaddwd mm3, [GOTOFF(ebx,PW_MF089_F060)] ; mm3=tmp3L |
| 322 | pmaddwd mm4, [GOTOFF(ebx,PW_MF089_F060)] ; mm4=tmp3H |
| 323 | |
| 324 | paddd mm2, MMWORD [wk(10)] ; mm2=tmp0L |
| 325 | paddd mm0, MMWORD [wk(11)] ; mm0=tmp0H |
| 326 | paddd mm3, mm5 ; mm3=tmp3L |
| 327 | paddd mm4, mm7 ; mm4=tmp3H |
| 328 | |
| 329 | movq MMWORD [wk(8)], mm2 ; wk(8)=tmp0L |
| 330 | movq MMWORD [wk(9)], mm0 ; wk(9)=tmp0H |
| 331 | |
| 332 | movq mm2, mm1 |
| 333 | movq mm0, mm1 |
| 334 | punpcklwd mm2, mm6 |
| 335 | punpckhwd mm0, mm6 |
| 336 | movq mm1, mm2 |
| 337 | movq mm6, mm0 |
| 338 | pmaddwd mm2, [GOTOFF(ebx,PW_MF050_MF256)] ; mm2=tmp1L |
| 339 | pmaddwd mm0, [GOTOFF(ebx,PW_MF050_MF256)] ; mm0=tmp1H |
| 340 | pmaddwd mm1, [GOTOFF(ebx,PW_MF256_F050)] ; mm1=tmp2L |
| 341 | pmaddwd mm6, [GOTOFF(ebx,PW_MF256_F050)] ; mm6=tmp2H |
| 342 | |
| 343 | paddd mm2, mm5 ; mm2=tmp1L |
| 344 | paddd mm0, mm7 ; mm0=tmp1H |
| 345 | paddd mm1, MMWORD [wk(10)] ; mm1=tmp2L |
| 346 | paddd mm6, MMWORD [wk(11)] ; mm6=tmp2H |
| 347 | |
| 348 | movq MMWORD [wk(10)], mm2 ; wk(10)=tmp1L |
| 349 | movq MMWORD [wk(11)], mm0 ; wk(11)=tmp1H |
| 350 | |
| 351 | ; -- Final output stage |
| 352 | |
| 353 | movq mm5, MMWORD [wk(0)] ; mm5=tmp10L |
| 354 | movq mm7, MMWORD [wk(1)] ; mm7=tmp10H |
| 355 | |
| 356 | movq mm2, mm5 |
| 357 | movq mm0, mm7 |
| 358 | paddd mm5, mm3 ; mm5=data0L |
| 359 | paddd mm7, mm4 ; mm7=data0H |
| 360 | psubd mm2, mm3 ; mm2=data7L |
| 361 | psubd mm0, mm4 ; mm0=data7H |
| 362 | |
| 363 | movq mm3, [GOTOFF(ebx,PD_DESCALE_P1)] ; mm3=[PD_DESCALE_P1] |
| 364 | |
| 365 | paddd mm5, mm3 |
| 366 | paddd mm7, mm3 |
| 367 | psrad mm5, DESCALE_P1 |
| 368 | psrad mm7, DESCALE_P1 |
| 369 | paddd mm2, mm3 |
| 370 | paddd mm0, mm3 |
| 371 | psrad mm2, DESCALE_P1 |
| 372 | psrad mm0, DESCALE_P1 |
| 373 | |
| 374 | packssdw mm5, mm7 ; mm5=data0=(00 01 02 03) |
| 375 | packssdw mm2, mm0 ; mm2=data7=(70 71 72 73) |
| 376 | |
| 377 | movq mm4, MMWORD [wk(4)] ; mm4=tmp11L |
| 378 | movq mm3, MMWORD [wk(5)] ; mm3=tmp11H |
| 379 | |
| 380 | movq mm7, mm4 |
| 381 | movq mm0, mm3 |
| 382 | paddd mm4, mm1 ; mm4=data1L |
| 383 | paddd mm3, mm6 ; mm3=data1H |
| 384 | psubd mm7, mm1 ; mm7=data6L |
| 385 | psubd mm0, mm6 ; mm0=data6H |
| 386 | |
| 387 | movq mm1, [GOTOFF(ebx,PD_DESCALE_P1)] ; mm1=[PD_DESCALE_P1] |
| 388 | |
| 389 | paddd mm4, mm1 |
| 390 | paddd mm3, mm1 |
| 391 | psrad mm4, DESCALE_P1 |
| 392 | psrad mm3, DESCALE_P1 |
| 393 | paddd mm7, mm1 |
| 394 | paddd mm0, mm1 |
| 395 | psrad mm7, DESCALE_P1 |
| 396 | psrad mm0, DESCALE_P1 |
| 397 | |
| 398 | packssdw mm4, mm3 ; mm4=data1=(10 11 12 13) |
| 399 | packssdw mm7, mm0 ; mm7=data6=(60 61 62 63) |
| 400 | |
| 401 | movq mm6, mm5 ; transpose coefficients(phase 1) |
| 402 | punpcklwd mm5, mm4 ; mm5=(00 10 01 11) |
| 403 | punpckhwd mm6, mm4 ; mm6=(02 12 03 13) |
| 404 | movq mm1, mm7 ; transpose coefficients(phase 1) |
| 405 | punpcklwd mm7, mm2 ; mm7=(60 70 61 71) |
| 406 | punpckhwd mm1, mm2 ; mm1=(62 72 63 73) |
| 407 | |
| 408 | movq mm3, MMWORD [wk(6)] ; mm3=tmp12L |
| 409 | movq mm0, MMWORD [wk(7)] ; mm0=tmp12H |
| 410 | movq mm4, MMWORD [wk(10)] ; mm4=tmp1L |
| 411 | movq mm2, MMWORD [wk(11)] ; mm2=tmp1H |
| 412 | |
| 413 | movq MMWORD [wk(0)], mm5 ; wk(0)=(00 10 01 11) |
| 414 | movq MMWORD [wk(1)], mm6 ; wk(1)=(02 12 03 13) |
| 415 | movq MMWORD [wk(4)], mm7 ; wk(4)=(60 70 61 71) |
| 416 | movq MMWORD [wk(5)], mm1 ; wk(5)=(62 72 63 73) |
| 417 | |
| 418 | movq mm5, mm3 |
| 419 | movq mm6, mm0 |
| 420 | paddd mm3, mm4 ; mm3=data2L |
| 421 | paddd mm0, mm2 ; mm0=data2H |
| 422 | psubd mm5, mm4 ; mm5=data5L |
| 423 | psubd mm6, mm2 ; mm6=data5H |
| 424 | |
| 425 | movq mm7, [GOTOFF(ebx,PD_DESCALE_P1)] ; mm7=[PD_DESCALE_P1] |
| 426 | |
| 427 | paddd mm3, mm7 |
| 428 | paddd mm0, mm7 |
| 429 | psrad mm3, DESCALE_P1 |
| 430 | psrad mm0, DESCALE_P1 |
| 431 | paddd mm5, mm7 |
| 432 | paddd mm6, mm7 |
| 433 | psrad mm5, DESCALE_P1 |
| 434 | psrad mm6, DESCALE_P1 |
| 435 | |
| 436 | packssdw mm3, mm0 ; mm3=data2=(20 21 22 23) |
| 437 | packssdw mm5, mm6 ; mm5=data5=(50 51 52 53) |
| 438 | |
| 439 | movq mm1, MMWORD [wk(2)] ; mm1=tmp13L |
| 440 | movq mm4, MMWORD [wk(3)] ; mm4=tmp13H |
| 441 | movq mm2, MMWORD [wk(8)] ; mm2=tmp0L |
| 442 | movq mm7, MMWORD [wk(9)] ; mm7=tmp0H |
| 443 | |
| 444 | movq mm0, mm1 |
| 445 | movq mm6, mm4 |
| 446 | paddd mm1, mm2 ; mm1=data3L |
| 447 | paddd mm4, mm7 ; mm4=data3H |
| 448 | psubd mm0, mm2 ; mm0=data4L |
| 449 | psubd mm6, mm7 ; mm6=data4H |
| 450 | |
| 451 | movq mm2, [GOTOFF(ebx,PD_DESCALE_P1)] ; mm2=[PD_DESCALE_P1] |
| 452 | |
| 453 | paddd mm1, mm2 |
| 454 | paddd mm4, mm2 |
| 455 | psrad mm1, DESCALE_P1 |
| 456 | psrad mm4, DESCALE_P1 |
| 457 | paddd mm0, mm2 |
| 458 | paddd mm6, mm2 |
| 459 | psrad mm0, DESCALE_P1 |
| 460 | psrad mm6, DESCALE_P1 |
| 461 | |
| 462 | packssdw mm1, mm4 ; mm1=data3=(30 31 32 33) |
| 463 | packssdw mm0, mm6 ; mm0=data4=(40 41 42 43) |
| 464 | |
| 465 | movq mm7, MMWORD [wk(0)] ; mm7=(00 10 01 11) |
| 466 | movq mm2, MMWORD [wk(1)] ; mm2=(02 12 03 13) |
| 467 | |
| 468 | movq mm4, mm3 ; transpose coefficients(phase 1) |
| 469 | punpcklwd mm3, mm1 ; mm3=(20 30 21 31) |
| 470 | punpckhwd mm4, mm1 ; mm4=(22 32 23 33) |
| 471 | movq mm6, mm0 ; transpose coefficients(phase 1) |
| 472 | punpcklwd mm0, mm5 ; mm0=(40 50 41 51) |
| 473 | punpckhwd mm6, mm5 ; mm6=(42 52 43 53) |
| 474 | |
| 475 | movq mm1, mm7 ; transpose coefficients(phase 2) |
| 476 | punpckldq mm7, mm3 ; mm7=(00 10 20 30) |
| 477 | punpckhdq mm1, mm3 ; mm1=(01 11 21 31) |
| 478 | movq mm5, mm2 ; transpose coefficients(phase 2) |
| 479 | punpckldq mm2, mm4 ; mm2=(02 12 22 32) |
| 480 | punpckhdq mm5, mm4 ; mm5=(03 13 23 33) |
| 481 | |
| 482 | movq mm3, MMWORD [wk(4)] ; mm3=(60 70 61 71) |
| 483 | movq mm4, MMWORD [wk(5)] ; mm4=(62 72 63 73) |
| 484 | |
| 485 | movq MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm7 |
| 486 | movq MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm1 |
| 487 | movq MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm2 |
| 488 | movq MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm5 |
| 489 | |
| 490 | movq mm7, mm0 ; transpose coefficients(phase 2) |
| 491 | punpckldq mm0, mm3 ; mm0=(40 50 60 70) |
| 492 | punpckhdq mm7, mm3 ; mm7=(41 51 61 71) |
| 493 | movq mm1, mm6 ; transpose coefficients(phase 2) |
| 494 | punpckldq mm6, mm4 ; mm6=(42 52 62 72) |
| 495 | punpckhdq mm1, mm4 ; mm1=(43 53 63 73) |
| 496 | |
| 497 | movq MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm0 |
| 498 | movq MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm7 |
| 499 | movq MMWORD [MMBLOCK(2,1,edi,SIZEOF_JCOEF)], mm6 |
| 500 | movq MMWORD [MMBLOCK(3,1,edi,SIZEOF_JCOEF)], mm1 |
| 501 | |
| 502 | .nextcolumn: |
| 503 | add esi, byte 4*SIZEOF_JCOEF ; coef_block |
| 504 | add edx, byte 4*SIZEOF_ISLOW_MULT_TYPE ; quantptr |
| 505 | add edi, byte 4*DCTSIZE*SIZEOF_JCOEF ; wsptr |
| 506 | dec ecx ; ctr |
| 507 | jnz near .columnloop |
| 508 | |
| 509 | ; ---- Pass 2: process rows from work array, store into output array. |
| 510 | |
| 511 | mov eax, [original_ebp] |
| 512 | lea esi, [workspace] ; JCOEF *wsptr |
| 513 | mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *) |
| 514 | mov eax, JDIMENSION [output_col(eax)] |
| 515 | mov ecx, DCTSIZE/4 ; ctr |
| 516 | alignx 16, 7 |
| 517 | .rowloop: |
| 518 | |
| 519 | ; -- Even part |
| 520 | |
| 521 | movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)] |
| 522 | movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)] |
| 523 | movq mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)] |
| 524 | movq mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)] |
| 525 | |
| 526 | ; (Original) |
| 527 | ; z1 = (z2 + z3) * 0.541196100; |
| 528 | ; tmp2 = z1 + z3 * -1.847759065; |
| 529 | ; tmp3 = z1 + z2 * 0.765366865; |
| 530 | ; |
| 531 | ; (This implementation) |
| 532 | ; tmp2 = z2 * 0.541196100 + z3 * (0.541196100 - 1.847759065); |
| 533 | ; tmp3 = z2 * (0.541196100 + 0.765366865) + z3 * 0.541196100; |
| 534 | |
| 535 | movq mm4, mm1 ; mm1=in2=z2 |
| 536 | movq mm5, mm1 |
| 537 | punpcklwd mm4, mm3 ; mm3=in6=z3 |
| 538 | punpckhwd mm5, mm3 |
| 539 | movq mm1, mm4 |
| 540 | movq mm3, mm5 |
| 541 | pmaddwd mm4, [GOTOFF(ebx,PW_F130_F054)] ; mm4=tmp3L |
| 542 | pmaddwd mm5, [GOTOFF(ebx,PW_F130_F054)] ; mm5=tmp3H |
| 543 | pmaddwd mm1, [GOTOFF(ebx,PW_F054_MF130)] ; mm1=tmp2L |
| 544 | pmaddwd mm3, [GOTOFF(ebx,PW_F054_MF130)] ; mm3=tmp2H |
| 545 | |
| 546 | movq mm6, mm0 |
| 547 | paddw mm0, mm2 ; mm0=in0+in4 |
| 548 | psubw mm6, mm2 ; mm6=in0-in4 |
| 549 | |
| 550 | pxor mm7, mm7 |
| 551 | pxor mm2, mm2 |
| 552 | punpcklwd mm7, mm0 ; mm7=tmp0L |
| 553 | punpckhwd mm2, mm0 ; mm2=tmp0H |
| 554 | psrad mm7, (16-CONST_BITS) ; psrad mm7,16 & pslld mm7,CONST_BITS |
| 555 | psrad mm2, (16-CONST_BITS) ; psrad mm2,16 & pslld mm2,CONST_BITS |
| 556 | |
| 557 | movq mm0, mm7 |
| 558 | paddd mm7, mm4 ; mm7=tmp10L |
| 559 | psubd mm0, mm4 ; mm0=tmp13L |
| 560 | movq mm4, mm2 |
| 561 | paddd mm2, mm5 ; mm2=tmp10H |
| 562 | psubd mm4, mm5 ; mm4=tmp13H |
| 563 | |
| 564 | movq MMWORD [wk(0)], mm7 ; wk(0)=tmp10L |
| 565 | movq MMWORD [wk(1)], mm2 ; wk(1)=tmp10H |
| 566 | movq MMWORD [wk(2)], mm0 ; wk(2)=tmp13L |
| 567 | movq MMWORD [wk(3)], mm4 ; wk(3)=tmp13H |
| 568 | |
| 569 | pxor mm5, mm5 |
| 570 | pxor mm7, mm7 |
| 571 | punpcklwd mm5, mm6 ; mm5=tmp1L |
| 572 | punpckhwd mm7, mm6 ; mm7=tmp1H |
| 573 | psrad mm5, (16-CONST_BITS) ; psrad mm5,16 & pslld mm5,CONST_BITS |
| 574 | psrad mm7, (16-CONST_BITS) ; psrad mm7,16 & pslld mm7,CONST_BITS |
| 575 | |
| 576 | movq mm2, mm5 |
| 577 | paddd mm5, mm1 ; mm5=tmp11L |
| 578 | psubd mm2, mm1 ; mm2=tmp12L |
| 579 | movq mm0, mm7 |
| 580 | paddd mm7, mm3 ; mm7=tmp11H |
| 581 | psubd mm0, mm3 ; mm0=tmp12H |
| 582 | |
| 583 | movq MMWORD [wk(4)], mm5 ; wk(4)=tmp11L |
| 584 | movq MMWORD [wk(5)], mm7 ; wk(5)=tmp11H |
| 585 | movq MMWORD [wk(6)], mm2 ; wk(6)=tmp12L |
| 586 | movq MMWORD [wk(7)], mm0 ; wk(7)=tmp12H |
| 587 | |
| 588 | ; -- Odd part |
| 589 | |
| 590 | movq mm4, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)] |
| 591 | movq mm6, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)] |
| 592 | movq mm1, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)] |
| 593 | movq mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)] |
| 594 | |
| 595 | movq mm5, mm6 |
| 596 | movq mm7, mm4 |
| 597 | paddw mm5, mm3 ; mm5=z3 |
| 598 | paddw mm7, mm1 ; mm7=z4 |
| 599 | |
| 600 | ; (Original) |
| 601 | ; z5 = (z3 + z4) * 1.175875602; |
| 602 | ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644; |
| 603 | ; z3 += z5; z4 += z5; |
| 604 | ; |
| 605 | ; (This implementation) |
| 606 | ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602; |
| 607 | ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644); |
| 608 | |
| 609 | movq mm2, mm5 |
| 610 | movq mm0, mm5 |
| 611 | punpcklwd mm2, mm7 |
| 612 | punpckhwd mm0, mm7 |
| 613 | movq mm5, mm2 |
| 614 | movq mm7, mm0 |
| 615 | pmaddwd mm2, [GOTOFF(ebx,PW_MF078_F117)] ; mm2=z3L |
| 616 | pmaddwd mm0, [GOTOFF(ebx,PW_MF078_F117)] ; mm0=z3H |
| 617 | pmaddwd mm5, [GOTOFF(ebx,PW_F117_F078)] ; mm5=z4L |
| 618 | pmaddwd mm7, [GOTOFF(ebx,PW_F117_F078)] ; mm7=z4H |
| 619 | |
| 620 | movq MMWORD [wk(10)], mm2 ; wk(10)=z3L |
| 621 | movq MMWORD [wk(11)], mm0 ; wk(11)=z3H |
| 622 | |
| 623 | ; (Original) |
| 624 | ; z1 = tmp0 + tmp3; z2 = tmp1 + tmp2; |
| 625 | ; tmp0 = tmp0 * 0.298631336; tmp1 = tmp1 * 2.053119869; |
| 626 | ; tmp2 = tmp2 * 3.072711026; tmp3 = tmp3 * 1.501321110; |
| 627 | ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447; |
| 628 | ; tmp0 += z1 + z3; tmp1 += z2 + z4; |
| 629 | ; tmp2 += z2 + z3; tmp3 += z1 + z4; |
| 630 | ; |
| 631 | ; (This implementation) |
| 632 | ; tmp0 = tmp0 * (0.298631336 - 0.899976223) + tmp3 * -0.899976223; |
| 633 | ; tmp1 = tmp1 * (2.053119869 - 2.562915447) + tmp2 * -2.562915447; |
| 634 | ; tmp2 = tmp1 * -2.562915447 + tmp2 * (3.072711026 - 2.562915447); |
| 635 | ; tmp3 = tmp0 * -0.899976223 + tmp3 * (1.501321110 - 0.899976223); |
| 636 | ; tmp0 += z3; tmp1 += z4; |
| 637 | ; tmp2 += z3; tmp3 += z4; |
| 638 | |
| 639 | movq mm2, mm3 |
| 640 | movq mm0, mm3 |
| 641 | punpcklwd mm2, mm4 |
| 642 | punpckhwd mm0, mm4 |
| 643 | movq mm3, mm2 |
| 644 | movq mm4, mm0 |
| 645 | pmaddwd mm2, [GOTOFF(ebx,PW_MF060_MF089)] ; mm2=tmp0L |
| 646 | pmaddwd mm0, [GOTOFF(ebx,PW_MF060_MF089)] ; mm0=tmp0H |
| 647 | pmaddwd mm3, [GOTOFF(ebx,PW_MF089_F060)] ; mm3=tmp3L |
| 648 | pmaddwd mm4, [GOTOFF(ebx,PW_MF089_F060)] ; mm4=tmp3H |
| 649 | |
| 650 | paddd mm2, MMWORD [wk(10)] ; mm2=tmp0L |
| 651 | paddd mm0, MMWORD [wk(11)] ; mm0=tmp0H |
| 652 | paddd mm3, mm5 ; mm3=tmp3L |
| 653 | paddd mm4, mm7 ; mm4=tmp3H |
| 654 | |
| 655 | movq MMWORD [wk(8)], mm2 ; wk(8)=tmp0L |
| 656 | movq MMWORD [wk(9)], mm0 ; wk(9)=tmp0H |
| 657 | |
| 658 | movq mm2, mm1 |
| 659 | movq mm0, mm1 |
| 660 | punpcklwd mm2, mm6 |
| 661 | punpckhwd mm0, mm6 |
| 662 | movq mm1, mm2 |
| 663 | movq mm6, mm0 |
| 664 | pmaddwd mm2, [GOTOFF(ebx,PW_MF050_MF256)] ; mm2=tmp1L |
| 665 | pmaddwd mm0, [GOTOFF(ebx,PW_MF050_MF256)] ; mm0=tmp1H |
| 666 | pmaddwd mm1, [GOTOFF(ebx,PW_MF256_F050)] ; mm1=tmp2L |
| 667 | pmaddwd mm6, [GOTOFF(ebx,PW_MF256_F050)] ; mm6=tmp2H |
| 668 | |
| 669 | paddd mm2, mm5 ; mm2=tmp1L |
| 670 | paddd mm0, mm7 ; mm0=tmp1H |
| 671 | paddd mm1, MMWORD [wk(10)] ; mm1=tmp2L |
| 672 | paddd mm6, MMWORD [wk(11)] ; mm6=tmp2H |
| 673 | |
| 674 | movq MMWORD [wk(10)], mm2 ; wk(10)=tmp1L |
| 675 | movq MMWORD [wk(11)], mm0 ; wk(11)=tmp1H |
| 676 | |
| 677 | ; -- Final output stage |
| 678 | |
| 679 | movq mm5, MMWORD [wk(0)] ; mm5=tmp10L |
| 680 | movq mm7, MMWORD [wk(1)] ; mm7=tmp10H |
| 681 | |
| 682 | movq mm2, mm5 |
| 683 | movq mm0, mm7 |
| 684 | paddd mm5, mm3 ; mm5=data0L |
| 685 | paddd mm7, mm4 ; mm7=data0H |
| 686 | psubd mm2, mm3 ; mm2=data7L |
| 687 | psubd mm0, mm4 ; mm0=data7H |
| 688 | |
| 689 | movq mm3, [GOTOFF(ebx,PD_DESCALE_P2)] ; mm3=[PD_DESCALE_P2] |
| 690 | |
| 691 | paddd mm5, mm3 |
| 692 | paddd mm7, mm3 |
| 693 | psrad mm5, DESCALE_P2 |
| 694 | psrad mm7, DESCALE_P2 |
| 695 | paddd mm2, mm3 |
| 696 | paddd mm0, mm3 |
| 697 | psrad mm2, DESCALE_P2 |
| 698 | psrad mm0, DESCALE_P2 |
| 699 | |
| 700 | packssdw mm5, mm7 ; mm5=data0=(00 10 20 30) |
| 701 | packssdw mm2, mm0 ; mm2=data7=(07 17 27 37) |
| 702 | |
| 703 | movq mm4, MMWORD [wk(4)] ; mm4=tmp11L |
| 704 | movq mm3, MMWORD [wk(5)] ; mm3=tmp11H |
| 705 | |
| 706 | movq mm7, mm4 |
| 707 | movq mm0, mm3 |
| 708 | paddd mm4, mm1 ; mm4=data1L |
| 709 | paddd mm3, mm6 ; mm3=data1H |
| 710 | psubd mm7, mm1 ; mm7=data6L |
| 711 | psubd mm0, mm6 ; mm0=data6H |
| 712 | |
| 713 | movq mm1, [GOTOFF(ebx,PD_DESCALE_P2)] ; mm1=[PD_DESCALE_P2] |
| 714 | |
| 715 | paddd mm4, mm1 |
| 716 | paddd mm3, mm1 |
| 717 | psrad mm4, DESCALE_P2 |
| 718 | psrad mm3, DESCALE_P2 |
| 719 | paddd mm7, mm1 |
| 720 | paddd mm0, mm1 |
| 721 | psrad mm7, DESCALE_P2 |
| 722 | psrad mm0, DESCALE_P2 |
| 723 | |
| 724 | packssdw mm4, mm3 ; mm4=data1=(01 11 21 31) |
| 725 | packssdw mm7, mm0 ; mm7=data6=(06 16 26 36) |
| 726 | |
| 727 | packsswb mm5, mm7 ; mm5=(00 10 20 30 06 16 26 36) |
| 728 | packsswb mm4, mm2 ; mm4=(01 11 21 31 07 17 27 37) |
| 729 | |
| 730 | movq mm6, MMWORD [wk(6)] ; mm6=tmp12L |
| 731 | movq mm1, MMWORD [wk(7)] ; mm1=tmp12H |
| 732 | movq mm3, MMWORD [wk(10)] ; mm3=tmp1L |
| 733 | movq mm0, MMWORD [wk(11)] ; mm0=tmp1H |
| 734 | |
| 735 | movq MMWORD [wk(0)], mm5 ; wk(0)=(00 10 20 30 06 16 26 36) |
| 736 | movq MMWORD [wk(1)], mm4 ; wk(1)=(01 11 21 31 07 17 27 37) |
| 737 | |
| 738 | movq mm7, mm6 |
| 739 | movq mm2, mm1 |
| 740 | paddd mm6, mm3 ; mm6=data2L |
| 741 | paddd mm1, mm0 ; mm1=data2H |
| 742 | psubd mm7, mm3 ; mm7=data5L |
| 743 | psubd mm2, mm0 ; mm2=data5H |
| 744 | |
| 745 | movq mm5, [GOTOFF(ebx,PD_DESCALE_P2)] ; mm5=[PD_DESCALE_P2] |
| 746 | |
| 747 | paddd mm6, mm5 |
| 748 | paddd mm1, mm5 |
| 749 | psrad mm6, DESCALE_P2 |
| 750 | psrad mm1, DESCALE_P2 |
| 751 | paddd mm7, mm5 |
| 752 | paddd mm2, mm5 |
| 753 | psrad mm7, DESCALE_P2 |
| 754 | psrad mm2, DESCALE_P2 |
| 755 | |
| 756 | packssdw mm6, mm1 ; mm6=data2=(02 12 22 32) |
| 757 | packssdw mm7, mm2 ; mm7=data5=(05 15 25 35) |
| 758 | |
| 759 | movq mm4, MMWORD [wk(2)] ; mm4=tmp13L |
| 760 | movq mm3, MMWORD [wk(3)] ; mm3=tmp13H |
| 761 | movq mm0, MMWORD [wk(8)] ; mm0=tmp0L |
| 762 | movq mm5, MMWORD [wk(9)] ; mm5=tmp0H |
| 763 | |
| 764 | movq mm1, mm4 |
| 765 | movq mm2, mm3 |
| 766 | paddd mm4, mm0 ; mm4=data3L |
| 767 | paddd mm3, mm5 ; mm3=data3H |
| 768 | psubd mm1, mm0 ; mm1=data4L |
| 769 | psubd mm2, mm5 ; mm2=data4H |
| 770 | |
| 771 | movq mm0, [GOTOFF(ebx,PD_DESCALE_P2)] ; mm0=[PD_DESCALE_P2] |
| 772 | |
| 773 | paddd mm4, mm0 |
| 774 | paddd mm3, mm0 |
| 775 | psrad mm4, DESCALE_P2 |
| 776 | psrad mm3, DESCALE_P2 |
| 777 | paddd mm1, mm0 |
| 778 | paddd mm2, mm0 |
| 779 | psrad mm1, DESCALE_P2 |
| 780 | psrad mm2, DESCALE_P2 |
| 781 | |
| 782 | movq mm5, [GOTOFF(ebx,PB_CENTERJSAMP)] ; mm5=[PB_CENTERJSAMP] |
| 783 | |
| 784 | packssdw mm4, mm3 ; mm4=data3=(03 13 23 33) |
| 785 | packssdw mm1, mm2 ; mm1=data4=(04 14 24 34) |
| 786 | |
| 787 | movq mm0, MMWORD [wk(0)] ; mm0=(00 10 20 30 06 16 26 36) |
| 788 | movq mm3, MMWORD [wk(1)] ; mm3=(01 11 21 31 07 17 27 37) |
| 789 | |
| 790 | packsswb mm6, mm1 ; mm6=(02 12 22 32 04 14 24 34) |
| 791 | packsswb mm4, mm7 ; mm4=(03 13 23 33 05 15 25 35) |
| 792 | |
| 793 | paddb mm0, mm5 |
| 794 | paddb mm3, mm5 |
| 795 | paddb mm6, mm5 |
| 796 | paddb mm4, mm5 |
| 797 | |
| 798 | movq mm2, mm0 ; transpose coefficients(phase 1) |
| 799 | punpcklbw mm0, mm3 ; mm0=(00 01 10 11 20 21 30 31) |
| 800 | punpckhbw mm2, mm3 ; mm2=(06 07 16 17 26 27 36 37) |
| 801 | movq mm1, mm6 ; transpose coefficients(phase 1) |
| 802 | punpcklbw mm6, mm4 ; mm6=(02 03 12 13 22 23 32 33) |
| 803 | punpckhbw mm1, mm4 ; mm1=(04 05 14 15 24 25 34 35) |
| 804 | |
| 805 | movq mm7, mm0 ; transpose coefficients(phase 2) |
| 806 | punpcklwd mm0, mm6 ; mm0=(00 01 02 03 10 11 12 13) |
| 807 | punpckhwd mm7, mm6 ; mm7=(20 21 22 23 30 31 32 33) |
| 808 | movq mm5, mm1 ; transpose coefficients(phase 2) |
| 809 | punpcklwd mm1, mm2 ; mm1=(04 05 06 07 14 15 16 17) |
| 810 | punpckhwd mm5, mm2 ; mm5=(24 25 26 27 34 35 36 37) |
| 811 | |
| 812 | movq mm3, mm0 ; transpose coefficients(phase 3) |
| 813 | punpckldq mm0, mm1 ; mm0=(00 01 02 03 04 05 06 07) |
| 814 | punpckhdq mm3, mm1 ; mm3=(10 11 12 13 14 15 16 17) |
| 815 | movq mm4, mm7 ; transpose coefficients(phase 3) |
| 816 | punpckldq mm7, mm5 ; mm7=(20 21 22 23 24 25 26 27) |
| 817 | punpckhdq mm4, mm5 ; mm4=(30 31 32 33 34 35 36 37) |
| 818 | |
| 819 | pushpic ebx ; save GOT address |
| 820 | |
| 821 | mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW] |
| 822 | mov ebx, JSAMPROW [edi+1*SIZEOF_JSAMPROW] |
| 823 | movq MMWORD [edx+eax*SIZEOF_JSAMPLE], mm0 |
| 824 | movq MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm3 |
| 825 | mov edx, JSAMPROW [edi+2*SIZEOF_JSAMPROW] |
| 826 | mov ebx, JSAMPROW [edi+3*SIZEOF_JSAMPROW] |
| 827 | movq MMWORD [edx+eax*SIZEOF_JSAMPLE], mm7 |
| 828 | movq MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm4 |
| 829 | |
| 830 | poppic ebx ; restore GOT address |
| 831 | |
| 832 | add esi, byte 4*SIZEOF_JCOEF ; wsptr |
| 833 | add edi, byte 4*SIZEOF_JSAMPROW |
| 834 | dec ecx ; ctr |
| 835 | jnz near .rowloop |
| 836 | |
| 837 | emms ; empty MMX state |
| 838 | |
| 839 | pop edi |
| 840 | pop esi |
| 841 | ; pop edx ; need not be preserved |
| 842 | ; pop ecx ; need not be preserved |
| 843 | pop ebx |
| 844 | mov esp, ebp ; esp <- aligned ebp |
| 845 | pop esp ; esp <- original ebp |
| 846 | pop ebp |
| 847 | ret |
| 848 | |
| 849 | ; For some reason, the OS X linker does not honor the request to align the |
| 850 | ; segment unless we do this. |
| 851 | align 32 |